package tv.grifo.transitions {
	import caurina.transitions.Tweener;
 
	/**
	 * @author Grifo.tv / Danilo Figueiredo - www.grifo.tv
	 */
 
	public class SleekTween {
 
		//------------------------------------
		// private, protected properties
		//------------------------------------
 
		private static const DIVISOR : Number = 0.5714285714285714; // Number up to 1
		private static const FIRST_HALF : Number = 0.21053; // Number up to 1 (FIRST_HALF plus SECOND_HALF should equal 1)
		private static const SECOND_HALF : Number = 0.78947; // Number up to 1 (FIRST_HALF plus SECOND_HALF should equal 1)
 
		//------------------------------------
		// public properties
		//------------------------------------
 
		//------------------------------------
		// constructor
		//------------------------------------
 
		public function SleekTween() {
			throw new Error("SleekTween is a static class and should not be instantiated.");
		}
 
		//
		// PRIVATE, PROTECTED
		//______________________________________________________________________
 
		private static function start(target : Object, parameters : Object) : void {
			// init tweens
			var firstTween : Object = {};
			var secondTween : Object = {};
 
			// filter properties from parameters
			var properties : Object = {};
			for (var param:String in parameters) {
				if(target.hasOwnProperty(param)) {
					properties[param] = parameters[param];
				}else if(param != "time" && param != "delay") {
					trace("Target has no property such as:", param);
				}
			}
 
			// set tweens properties
			for (var prop:String in properties) {
				firstTween[prop] = (properties[prop] - target[prop]) * DIVISOR + target[prop];
				secondTween[prop] = properties[prop];
			}
			// set tweens time
			if (!Boolean(parameters["time"])) parameters["time"] = 2; // set default time to 2 if undefined
			firstTween["time"] = parameters["time"] * FIRST_HALF;
			secondTween["time"] = parameters["time"] * SECOND_HALF;
 
			// set tweens transition
			firstTween["transition"] = "easeInExpo";
			secondTween["transition"] = "easeOutExpo";
 
			// set tweens delay
			if (Boolean(parameters["delay"])) {
				firstTween["delay"] = parameters["delay"];
			} else {
				firstTween["delay"] = 0;
			}
			secondTween["delay"] = firstTween["time"] + firstTween["delay"];
			secondTween["onComplete"] = parameters["onComplete"];
			secondTween["onCompleteParams"] = parameters["onCompleteParams"];
 
			// do tween
			Tweener.addTween(target, firstTween);
			Tweener.addTween(target, secondTween);
		}
 
		//
		// PUBLIC
		//______________________________________________________________________
 
		public static function addTween(target : Object = null, parameters : Object = null) : void {
			if (!Boolean(target) || !Boolean(parameters)) return;
			start(target, parameters);
		}
	}
}

SleekTween.addTween(target, {scaleX:tweenScaleX, time:2});